Learning with GP: Taylor coefficients of xi(s) - Gram

[Jacques Gélinas <jacquesg00@hotmail.com>]

The Riemann Hypothesis (RH) is the conjecture that the real
and even entire function Xi(t) below has real zeros.
The xis(s) notation is due to Landau. Riemann, Hadamard, Jensen,
Gram, Polya, ... studied the function Xi(t), denoting it by xi(t).
The functional equation xi(s)=xi(1-s) avoids the poles of gamma(s).

Gram [1] computed by hand the first non-zero Maclaurin coefficients of 
the logarithm of Xi(t) (seven using 16D in 1895; ten using 28D in 1903),
by interpolating values of xi derived from those of Sieltjes for zeta(n).
He also gave the expansion Xigram(t) below "for small values of t" [2].

We will use Pari 2.11 to check the accuracy of some Gram's results,
which he estimated to be at least 15 correct digits, from his values 
for the zeros of Xi(t) (8D for the first 10, 3D for the next 5).

\\------------------------------------------- Start cut

xis(s) = gamma(1+s/2)/Pi^(s/2)*(s-1)*zeta(s);
\\     = lfunlambda(1,s)*binomial(s,2)    (Bill Alombert)

xi(s=1/2) = {
  if( s==0 || s==1, return( 1/2 ) );
  if( real(s) == 1/2, return( real( xis(s) ) ));
  if( real(s) <  1/2, return( xis(1-s) ));
  xis(s);
}
addhelp(xi,"xi(s): Riemann's entire xi-function at s");

Xi(t=0) = xi(1/2+I*t);
addhelp(Xi,"Xi(t): Riemann's entire function xi(1/2+it)");

lXigram(t) = {                   \\Gram,1903
 -6.98922267945331415298362020481E-01
  -2.3104993115418970788932387131E-02 * t^02
             -1.85862996426348428E-05 * t^04
               -4.805797713365663E-08 * t^06
                 -1.6575792006235E-10 * t^08
                    -6.4273282993E-13 * t^10
                     -2.646155724E-15 * t^12
                      -1.12904605E-17 * t^14
                         -4.93322E-20 * t^16
                           -2.206E-22 * t^18
;}

\\ xi-abcissas: 1/2,1,2,...,15;   Xi(it) == xi(1/2+t)
NX = 15;        \\Gram,1895
tgram = concat(0, [k-1/2 | k<-[1..NX]]);
ygram = [ log(Xi(I*t)) | t<-tgram ];
lXipari(x) = polinterpolate(apply(sqr,tgram),ygram,x);

zetah = -1.4603545088095868128894991525125; \\Gram,1895
xih = 0.4971207781883141; \\Gram,1895

Xigramv = xih * {[1, -2.31049931154190E-2,
        +2.483340537892E-4, -1.6743526280E-6, +8.0306974E-9,
        -2.94014E-11, +8.60E-14, -2E-16 ];}   \\Gram,1895
Xigram(t) = sum(k=0, NX\2, Xigramv[k+1] * t^(2*k) );

\\ Pari 2.10+ needed; zeta(1/2+I*t) implemented in 2.11.1+
Xipari(t) = real(subst(Pol(xis(1/2+x+O(x^NX))),x,I*t));
Xinumd(t) = sum(k=0, NX\2, t^(2*k) / (2*k)! \
                               * derivnum(t=0,Xi(t),2*k) );

{[
  abs( 1 - zetah/zeta(1/2) ) < 2E-30,
  abs( 1 -   xih/xi(1/2)   ) < 2E-17,
  normlp(   lXipari(-t^2)        - lXigram(t) ) < 3E-17,
  normlp( Pol(exp(lXigram(t)),t) -  Xigram(t) ) < 3E-17,
  normlp( Xipari(t) - Xigram(t) ) < 3E-17,
  normlp( Xipari(t) - Xinumd(t) ) < 10^(8-precision(1.))
]};
print("Tests passed : ",vecsum(%)," out of ",#%);

\\-------------------------------------------- End paste

------------------------------ Features used [3,4]
gamma, zeta, real, polinterpolate, apply, sqr, Vec, exp(series), 
derivnum(,,ind), normlp, addhelp, [taylor(xis(1/2+x,x,15)]

------------------------------ References
[1] Gram (1903) Note sur les zéros de la fonction zeta(s) de Riemann. 
http://projecteuclid.org/download/pdf_1/euclid.acta/1485882163
[2] Adams+Hippisley (1922) Smithsonian mathematical formulae and tables
#6.364: logarithm and exponential of series (Arbogast,1800,Du calcul des dérivations).
http://archive.org/details/smithsonianmathe00smitrich/page/120
[3] Tutorial: http://pari.math.u-bordeaux.fr/pub/pari/manuals/2.11.0/tutorial.pdf
[4] Reference card: http://pari.math.u-bordeaux.fr/pub/pari/manuals/2.11.0/refcard.pdf

Jacques Gélinas          Next: Taylor coefficients of xi(s) - Lyness+Moler